Application.onConnectAccept

Server-Side Communication ActionScript > Application.onConnectAccept

Availability

Flash Communication Server MX (with communication components only)

Usage

application.onConnectAccept = function (clientObj [,p1, ..., pN]){
	//insert code here to indicate result of an accepted connection
};

Parameters

clientObj The client connecting to the application.

p1...pN Optional parameters passed to the application.onConnectAccept method. These parameters are passed from the client-side NetConnection.connect method when a client connects to the application.

Returns

Nothing.

Description

Event handler; invoked only when the communication components are used (that is, when the components.asc script is loaded into your server-side application script). application.onConnectAccept is invoked on the server side when NetConnection.connect is called from the client side and a client successfully connects to an application instance.

When you use components, your last line (in order of execution) of the onConnect method should be either application.acceptConnection or application.rejectConnection. Any logic that follows the explicit acceptConnection or rejectConnection statement needs to go into application.onConnectAccept and application.onConnectReject statements, or it will be ignored. This requirement exists only when you use components.

Example

The first example is the client-side code you would use for an application:

nc = new NetConnection();

//try either username
nc.connect("rtmp:/test","jlopes");
//nc.connect("rtmp:/test","hacker");

nc.onStatus = function(info) {trace(info.code);}

nc.doSomething = function(){
	trace("doSomething called!");
}

The second example is server-side code you would include in your application's main.asc file:

//When using components, always load components.asc
load( "components.asc" );

application.onConnect = function(client, username){
	trace("onConnect called");
 	gFrameworkFC.getClientGlobals(client).username = username;
	if (username == "hacker") {
		application.rejectConnection(client);
	} 
	else {
		application.acceptConnection(client);
	}
}

//Code is in onConnectAccept and onConnectReject statements, because components are used
application.onConnectAccept = function(client, username){
	trace("Connection accepted for "+username);
	client.call("doSomething",null);
}

application.onConnectReject = function(client, username){
	trace("Connection rejected for "+username);
}